Heroic Launcher 🫠

4 files changed, 294 insertions, 0 deletions

diff --git a/pkgs/heroic-launcher/default.nix b/pkgs/heroic-launcher/default.nix
new file mode 100644
index 0000000..96ece24
--- /dev/null
+++ b/pkgs/heroic-launcher/default.nix
@@ -0,0 +1,118 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, fetchYarnDeps
+, yarn
+, fixup_yarn_lock
+, nodejs
+, python3
+, makeWrapper
+, electron
+, vulkan-helper
+, gogdl
+, legendary-gl
+, nile
+}:
+
+let appName = "heroic";
+in stdenv.mkDerivation rec {
+  pname = "heroic-unwrapped";
+  version = "2.9.1";
+
+  src = fetchFromGitHub {
+    owner = "Heroic-Games-Launcher";
+    repo = "HeroicGamesLauncher";
+    rev = "v${version}";
+    hash = "sha256-kCvMUhN1kjGb5rV+lkKm1FFYBJUSQGOKTY1DQdiAWLU=";
+  };
+
+  offlineCache = fetchYarnDeps {
+    yarnLock = "${src}/yarn.lock";
+    hash = "sha256-kHZL7TENVK58dvr8PBFtWYZ2PSKEYESX4e1xYmMA5+Y=";
+  };
+
+  nativeBuildInputs = [
+    yarn
+    fixup_yarn_lock
+    nodejs
+    python3
+    makeWrapper
+  ];
+
+  patches = [
+    # Reverts part of upstream PR 2761 so that we don't have to use a non-free Electron fork.
+    # https://github.com/Heroic-Games-Launcher/HeroicGamesLauncher/pull/2761
+    ./remove-drm-support.patch
+    # Make Heroic create Steam shortcuts (to non-steam games) with the correct path to heroic.
+    ./fix-non-steam-shortcuts.patch
+  ];
+
+  configurePhase = ''
+    runHook preConfigure
+
+    export HOME=$(mktemp -d)
+    yarn config --offline set yarn-offline-mirror $offlineCache
+    fixup_yarn_lock yarn.lock
+    yarn install --offline --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive
+    patchShebangs node_modules/
+
+    runHook postConfigure
+  '';
+
+  buildPhase = ''
+    runHook preBuild
+
+    yarn --offline vite build
+
+    # Remove dev dependencies.
+    yarn install --production --offline --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive
+
+    runHook postBuild
+  '';
+
+  # --disable-gpu-compositing is to work around upstream bug
+  # https://github.com/electron/electron/issues/32317
+  installPhase = let
+    binPlatform = if stdenv.isDarwin then "darwin" else "linux";
+  in ''
+    runHook preInstall
+
+    mkdir -p $out/share/{applications,${appName}}
+    cp -r . $out/share/${appName}
+    rm -rf $out/share/${appName}/{.devcontainer,.vscode,.husky,.idea,.github}
+
+    chmod -R u+w "$out/share/${appName}/public/bin" "$out/share/${appName}/build/bin"
+    rm -rf "$out/share/${appName}/public/bin" "$out/share/${appName}/build/bin"
+    mkdir -p "$out/share/${appName}/build/bin/${binPlatform}"
+    ln -s \
+      "${gogdl}/bin/gogdl" \
+      "${legendary-gl}/bin/legendary" \
+      "${nile}/bin/nile" \
+      "${lib.optionalString stdenv.isLinux "${vulkan-helper}/bin/vulkan-helper"}" \
+      "$out/share/${appName}/build/bin/${binPlatform}"
+
+    makeWrapper "${electron}/bin/electron" "$out/bin/heroic" \
+      --inherit-argv0 \
+      --add-flags --disable-gpu-compositing \
+      --add-flags $out/share/${appName} \
+      --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations --enable-wayland-ime}}"
+
+    substituteInPlace "$out/share/${appName}/flatpak/com.heroicgameslauncher.hgl.desktop" \
+      --replace "Exec=heroic-run" "Exec=heroic"
+    mkdir -p "$out/share/applications" "$out/share/icons/hicolor/512x512/apps"
+    ln -s "$out/share/${appName}/flatpak/com.heroicgameslauncher.hgl.desktop" "$out/share/applications"
+    ln -s "$out/share/${appName}/flatpak/com.heroicgameslauncher.hgl.png" "$out/share/icons/hicolor/512x512/apps"
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "A Native GOG, Epic, and Amazon Games Launcher for Linux, Windows and Mac";
+    homepage = "https://github.com/Heroic-Games-Launcher/HeroicGamesLauncher";
+    changelog = "https://github.com/Heroic-Games-Launcher/HeroicGamesLauncher/releases";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ aidalgol ];
+    platforms = [ "x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin" ];
+    mainProgram = appName;
+  };
+}
diff --git a/pkgs/heroic-launcher/fhsenv.nix b/pkgs/heroic-launcher/fhsenv.nix
new file mode 100644
index 0000000..19b44b2
--- /dev/null
+++ b/pkgs/heroic-launcher/fhsenv.nix
@@ -0,0 +1,139 @@
+{ buildFHSEnv
+, heroic-unwrapped
+, extraPkgs ? pkgs: [ ]
+, extraLibraries ? pkgs: [ ]
+}:
+
+buildFHSEnv {
+  name = "heroic";
+
+  runScript = "heroic";
+
+  # Many Wine and native games need 32-bit libraries.
+  multiArch = true;
+
+  # required by Electron
+  unshareIpc = false;
+
+  targetPkgs = pkgs: with pkgs; [
+    heroic-unwrapped
+    gamemode
+    curl
+    gawk
+    gnome.zenity
+    plasma5Packages.kdialog
+    mangohud
+    nettools
+    opencl-headers
+    p7zip
+    perl
+    psmisc
+    python3
+    which
+    xorg.xrandr
+    zstd
+  ] ++ extraPkgs pkgs;
+
+  multiPkgs = let
+    xorgDeps = pkgs: with pkgs.xorg; [
+      libpthreadstubs
+      libSM
+      libX11
+      libXaw
+      libxcb
+      libXcomposite
+      libXcursor
+      libXdmcp
+      libXext
+      libXi
+      libXinerama
+      libXmu
+      libXrandr
+      libXrender
+      libXv
+      libXxf86vm
+    ];
+    gstreamerDeps = pkgs: with pkgs.gst_all_1; [
+      gstreamer
+      gst-plugins-base
+      gst-plugins-good
+      gst-plugins-ugly
+      gst-plugins-bad
+      gst-libav
+    ];
+  in pkgs: with pkgs; [
+    alsa-lib
+    alsa-plugins
+    bash
+    cabextract
+    cairo
+    coreutils
+    cups
+    dbus
+    freealut
+    freetype
+    fribidi
+    giflib
+    glib
+    gnutls
+    gtk3
+    lcms2
+    libevdev
+    libgcrypt
+    libGLU
+    libglvnd
+    libgpg-error
+    libgudev
+    libjpeg
+    libkrb5
+    libmpeg2
+    libogg
+    libopus
+    libpng
+    libpulseaudio
+    libselinux
+    libsndfile
+    libsoup
+    libtheora
+    libtiff
+    libusb1
+    libv4l
+    libva
+    libvdpau
+    libvorbis
+    libvpx
+    libwebp
+    libxkbcommon
+    libxml2
+    mpg123
+    ncurses
+    ocl-icd
+    openal
+    openldap
+    openssl
+    pango
+    pipewire
+    samba4
+    sane-backends
+    SDL2
+    speex
+    sqlite
+    udev
+    unixODBC
+    util-linux
+    v4l-utils
+    vulkan-loader
+    wayland
+    zlib
+  ] ++ xorgDeps pkgs
+    ++ gstreamerDeps pkgs
+    ++ extraLibraries pkgs;
+
+  extraInstallCommands = ''
+    mkdir -p $out/share
+    ln -s ${heroic-unwrapped}/share/applications $out/share
+    ln -s ${heroic-unwrapped}/share/icons $out/share
+  '';
+
+  meta = heroic-unwrapped.meta;
+}
diff --git a/pkgs/heroic-launcher/fix-non-steam-shortcuts.patch b/pkgs/heroic-launcher/fix-non-steam-shortcuts.patch
new file mode 100644
index 0000000..7b46473
--- /dev/null
+++ b/pkgs/heroic-launcher/fix-non-steam-shortcuts.patch
@@ -0,0 +1,13 @@
+diff --git a/src/backend/shortcuts/nonesteamgame/nonesteamgame.ts b/src/backend/shortcuts/nonesteamgame/nonesteamgame.ts
+index ebef6aa4..c8bd853d 100644
+--- a/src/backend/shortcuts/nonesteamgame/nonesteamgame.ts
++++ b/src/backend/shortcuts/nonesteamgame/nonesteamgame.ts
+@@ -252,7 +252,7 @@ async function addNonSteamGame(props: {
+     // add new Entry
+     const newEntry = {} as ShortcutEntry
+     newEntry.AppName = props.gameInfo.title
+-    newEntry.Exe = `"${app.getPath('exe')}"`
++    newEntry.Exe = `"heroic"`
+     newEntry.StartDir = `"${process.cwd()}"`
+ 
+     if (isFlatpak) {
diff --git a/pkgs/heroic-launcher/remove-drm-support.patch b/pkgs/heroic-launcher/remove-drm-support.patch
new file mode 100644
index 0000000..f3cd80f
--- /dev/null
+++ b/pkgs/heroic-launcher/remove-drm-support.patch
@@ -0,0 +1,24 @@
+diff --git a/src/backend/main.ts b/src/backend/main.ts
+index 2cd1a28f..a60e04d0 100644
+--- a/src/backend/main.ts
++++ b/src/backend/main.ts
+@@ -19,8 +19,7 @@ import {
+   powerSaveBlocker,
+   protocol,
+   screen,
+-  clipboard,
+-  components
++  clipboard
+ } from 'electron'
+ import 'backend/updater'
+ import { autoUpdater } from 'electron-updater'
+@@ -286,8 +285,7 @@ if (!gotTheLock) {
+     initImagesCache()
+ 
+     if (!process.env.CI) {
+-      await components.whenReady()
+-      logInfo(['DRM module staus', components.status()])
++      logInfo('DRM modules disabled for nixpkgs')
+     }
+ 
+     // try to fix notification app name on windows