flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

{
  description = "jp3's dmenu";

  outputs = { self, nixpkgs }:
    let
      system = "x86_64-linux";

      overlay = final: prev: {
        dmenu = prev.dmenu.overrideAttrs (old: {
          version = "5.2";
          src = builtins.path { path = ./.; name = "dmenu"; };
        });
      };

      dmenu = (
        import nixpkgs {
          inherit system;
          overlays = [ overlay ];
        }
      ).dmenu;
    in
    {
      overlays.default = overlay;

      packages.${system}.default = dmenu;

      checks.${system} = {
        build = dmenu;

        version = nixpkgs.legacyPackages.${system}.runCommand "version-check" { } ''
          dmenu_version="$(${dmenu}/bin/dmenu -v)"

          echo "package version: ${dmenu.name}"
          echo "dmenu version:   $dmenu_version"

          [[ "${dmenu.name}" == "$dmenu_version" ]]
          touch ${placeholder "out"}
        '';
      };
    };
}