{
  addOpenGLRunpath,
  copyDesktopItems,
  flite,
  glib-networking,
  jdk17,
  jdk8,
  jdks ? [jdk8 jdk17],
  lib,
  libGL,
  libpulseaudio,
  modrinth-app-unwrapped,
  stdenv,
  symlinkJoin,
  udev,
  wrapGAppsHook,
  xorg,
}:
symlinkJoin {
  name = "modrinth-app-${modrinth-app-unwrapped.version}";

  paths = [modrinth-app-unwrapped];

  buildInputs = [
    glib-networking
    copyDesktopItems
  ];

  nativeBuildInputs = [
    wrapGAppsHook
  ];

  postBuild = let
    libPath = lib.makeLibraryPath [
      flite # narrator support
      libGL
      libpulseaudio
      stdenv.cc.cc.lib

      udev # oshi

      # lwjgl
      xorg.libX11
      xorg.libXcursor
      xorg.libXext
      xorg.libXxf86vm
      xorg.libXrandr
    ];

    binPath = lib.makeBinPath (
      lib.optionals stdenv.isLinux [xorg.xrandr]
    );

    args =
      ["--prefix PATH : ${lib.makeSearchPath "bin/java" jdks}"]
      ++ lib.optionals stdenv.isLinux [
        "--set LD_LIBRARY_PATH ${addOpenGLRunpath.driverLink}/lib:${libPath}"
        "--prefix PATH : ${binPath}"
      ];
  in ''
    gappsWrapperArgs+=(
      ${lib.concatStringsSep "\n" args}
    )

    wrapGAppsHook
  '';

  postInstall = ''
    copyDesktopItems
  '';

  inherit (modrinth-app-unwrapped) meta;
}