From 230ac000af9de06b42edd4f960a7a69fa5416798 Mon Sep 17 00:00:00 2001
From: Jakub Trzeciak <jptrzy@gmail.com>
Date: Thu, 9 Nov 2023 20:18:03 +0100
Subject: Modrinth App

---
 pkgs/modrinth-app/wrapper.nix | 73 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 pkgs/modrinth-app/wrapper.nix

(limited to 'pkgs/modrinth-app/wrapper.nix')

diff --git a/pkgs/modrinth-app/wrapper.nix b/pkgs/modrinth-app/wrapper.nix
new file mode 100644
index 0000000..bfb2823
--- /dev/null
+++ b/pkgs/modrinth-app/wrapper.nix
@@ -0,0 +1,73 @@
+{
+  addOpenGLRunpath,
+  copyDesktopItems,
+  flite,
+  glib-networking,
+  jdk17,
+  jdk8,
+  jdks ? [jdk8 jdk17],
+  lib,
+  libGL,
+  libpulseaudio,
+  modrinth-app-unwrapped,
+  stdenv,
+  symlinkJoin,
+  udev,
+  wrapGAppsHook,
+  xorg,
+}:
+symlinkJoin {
+  name = "modrinth-app-${modrinth-app-unwrapped.version}";
+
+  paths = [modrinth-app-unwrapped];
+
+  buildInputs = [
+    glib-networking
+    copyDesktopItems
+  ];
+
+  nativeBuildInputs = [
+    wrapGAppsHook
+  ];
+
+  postBuild = let
+    libPath = lib.makeLibraryPath [
+      flite # narrator support
+      libGL
+      libpulseaudio
+      stdenv.cc.cc.lib
+
+      udev # oshi
+
+      # lwjgl
+      xorg.libX11
+      xorg.libXcursor
+      xorg.libXext
+      xorg.libXxf86vm
+      xorg.libXrandr
+    ];
+
+    binPath = lib.makeBinPath (
+      lib.optionals stdenv.isLinux [xorg.xrandr]
+    );
+
+    args =
+      ["--prefix PATH : ${lib.makeSearchPath "bin/java" jdks}"]
+      ++ lib.optionals stdenv.isLinux [
+        "--set LD_LIBRARY_PATH ${addOpenGLRunpath.driverLink}/lib:${libPath}"
+        "--prefix PATH : ${binPath}"
+      ];
+  in ''
+    gappsWrapperArgs+=(
+      ${lib.concatStringsSep "\n" args}
+    )
+
+    wrapGAppsHook
+  '';
+
+  postInstall = ''
+    copyDesktopItems
+  '';
+
+  inherit (modrinth-app-unwrapped) meta;
+}
-- 
cgit v1.2.3